THMMY.gr

;Input Parameters: 
;	celsius_tem: the temperature in Celsius degrees - stored in R16
;Other variables:
;	farenheit_tem: the temperature in Farenheit degrees (output parameter)
;		temporary storage of the integer part of the subtotal - stored in R19
;	fract_part: storage of the fractional part of the subtotal - stored in R18
;Exit: "farehheit_tem" holds the temperature in Farenheit degrees
;Errors: celsius_tem>124 --> sets T flag (unappointed value of Celsius temperature)
;Comments: 
;	- 0.8 ~= 0b0.11001101
;	0.5+0.25+(0*0.125+0*0.625)+0.03125+0.015625+(0*0.0078125)+0.00390625= 0.80078125
;	max Divergence is neglectable (<0.1) even for max C (0.00078125*124=0.096875)
;	- Since the result is rounded to the closest integer, divergence's negative
;	effect is limited!
;--------------------
.def celsius_tem=R16 
.def farenheit_tem=R19
.def fract_part=R18
.set offset=32
;----------
TCONV_CELS_FAR_FUNCT_FB:
	clr fract_part
	cpi celsius_tem, 125
	brsh overfl_value
	mov farenheit_tem, celsius_tem	; (add temp/256)
	lsr farenheit_tem
	ror fract_part					
	lsr farenheit_tem			; (temp/128 not used)
	ror fract_part
	add farenheit_tem, celsius_tem	; (add temp/64)
	ror farenheit_tem
	ror fract_part
	add farenheit_tem, celsius_tem	; (add temp/32)
	ror farenheit_tem
	ror fract_part		
	lsr farenheit_tem			; (temp/16 not used)
	ror fract_part	
	lsr farenheit_tem			; (temp/8 not used)
	ror fract_part
	add farenheit_tem, celsius_tem	; (add temp/4)
	ror farenheit_tem
	ror fract_part
	add farenheit_tem, celsius_tem	; (add temp/2)
	ror farenheit_tem
	ror fract_part
	sbrc fract_part, 7			; check for rounding to the upper integer
	inc farenheit_tem
	add farenheit_tem, celsius_tem	; (add temp)
	ldi fract_part, offset
	add	farenheit_tem, fract_part 	; adding 32 to the product part of the function
	clt
	ret
overfl_value:
	set
	ret
;----- End of subroutine TCONV_CELS_FAR_FUNCT_FB -----
.undef celsius_tem
.undef farenheit_tem
.undef fract_part